10 REM FRACTALS (BASIC-STEUERPGM)
20 REM V1.4 VOM 23.11.1986
30 REM FUER C64 UND VC1541
40 REM GESCHRIEBEN VON
50 REM I. CAMPHAUSEN
60 :
70 :
80 :
100 IF A=0 THEN PRINT"[147]";TAB(13);"BITTE WARTEN!"
110 IF A=0 THEN POKE55,0:POKE 56,96:CLR:A=1:LOAD"FRACTALE 9.0",8,1
120 IF A=1 THEN A=2:LOAD"MENUEZEILE",8,1
130 IF A=2 THEN A=3:LOAD"BIENE/MAUS",8,1
140 :
400 REM
410 REM **************************
420 REM EINSPRUNGSADRESSEN FUER MC
430 REM **************************
440 REM
500 RU=32799
510 R2=32823
520 BEFEHL=35115
530 GIN=32995
540 TASTE=35601
550 DIR=35617
560 NLAENGE=35887
570 DLOA=35888
580 DSAV=35901
590 GLOA=35924
600 GSAV=35937
610 :
620 A1(1)=DL:A1(2)=DS:A1(3)=GL:A1(4)=GS
630 A2(1)=RU:A2(2)=R2:A2(3)=GIN:A2(4)=R2
640 FOR I=1 TO 6:READ AD(I):NEXT I
650 DATA 24576,24608,24640,26656,26688,28736
660 FOR I=1 TO 4:READ UE$(I):NEXT I
670 DATA " DLOAD "," DSAVE "," GLOAD "," GSAVE "
680 :
690 :
1000 REM
1010 REM *************
1020 REM HAUPTPROGRAMM
1030 REM *************
1040 REM
1050 SYS 32768
1060 :
1070 NR=PEEK(BEFEHL)-2:IF NR>0 THEN GOSUB 3000:GOTO 1070
1080 GOSUB 2000:GOTO 1070
1090 :
1100 :
2000 REM
2010 REM ************************
2020 REM UP STUETZPUNKTE EINGEBEN
2030 REM ************************
2040 REM
2050 PRINT:PRINT
2060 FOR I=1 TO 6
2070 :  H=0
2080 :  PRINT"HOEHE"I"[157]. STUETZPUNKT ";:INPUT H
2090 :  IF ABS(H)>30 THEN PRINT"BITTE BEACHTEN: -30 <= HOEHE <= +30![146]":GOTO2080
2100 :  IF H<0 THEN H=256+H
2110 :  POKE AD(I),H
2120 NEXT I
2130 SYS RU
2140 RETURN
2150 :
2160 :
3000 REM
3010 REM ******************
3020 REM UP LADEN/SPEICHERN
3030 REM ******************
3040 REM
3050 PRINT "[147][144]****************************************"
3060 PRINT "";TAB((40-LEN(UE$(NR)))/2);UE$(NR)
3070 N$="":INPUT"FILENAME ";N$
3080 IF N$="" THEN SYS R2:RETURN
3090 IF N$="$"THEN SYS DIR:GOSUB 4000:IF FE=0 THEN SYS TASTE:GOTO 3000
3100 IF NR<3 THEN N$=CHR$(4)+N$
3110 IF NR>2 THEN N$=CHR$(7)+N$
3120 POKE NL,LEN(N$)
3130 FOR I=1 TO LEN(N$):POKE 703+I,ASC(MID$(N$,I,1)):NEXT I
3140 SYS A1(NR):GOSUB 4000:IF FE<>0 THEN 3000
3150 SYS A2(NR)
3160 RETURN
3170 :
3180 :
4000 REM
4010 REM ***********************
4020 REM UP FEHLERKANAL ABFRAGEN
4030 REM ***********************
4040 REM
4050 OPEN 1,8,15:INPUT#1,FE,FE$,A,B:CLOSE 1                    
4060 PRINT:PRINT FE,FE$:IF FE<>0 THEN SYS TASTE
4070 RETURN